initial: dev environment flake and task prompt
This commit is contained in:
@@ -0,0 +1,79 @@
|
||||
{
|
||||
description = "Heltec WiFi LoRa 32 V4.3 wM-Bus C1 repeater HIL development environment";
|
||||
|
||||
inputs = {
|
||||
nixpkgs.url = "github:NixOS/nixpkgs/nixos-25.11";
|
||||
esp-dev = {
|
||||
url = "github:mirrexagon/nixpkgs-esp-dev/5287d6e1ca9e15ebd5113c41b9590c468e1e001b";
|
||||
};
|
||||
};
|
||||
|
||||
outputs = { self, nixpkgs, esp-dev }:
|
||||
let
|
||||
system = "x86_64-linux";
|
||||
pkgs = import nixpkgs { inherit system; };
|
||||
|
||||
rtl-wmbus = pkgs.stdenv.mkDerivation {
|
||||
pname = "rtl-wmbus";
|
||||
version = "2024-08-26";
|
||||
src = pkgs.fetchFromGitHub {
|
||||
owner = "xaelsouth";
|
||||
repo = "rtl-wmbus";
|
||||
rev = "34684e655df70867ac86e799561ec6512c45be0a";
|
||||
hash = "sha256-hqlvL0EhmxZ5NxyCxOB1a7S9mEnWrkUrrh7EPdXSN7k=";
|
||||
};
|
||||
buildPhase = ''
|
||||
runHook preBuild
|
||||
make release
|
||||
runHook postBuild
|
||||
'';
|
||||
installPhase = ''
|
||||
runHook preInstall
|
||||
install -Dm755 build/rtl_wmbus $out/bin/rtl_wmbus
|
||||
runHook postInstall
|
||||
'';
|
||||
};
|
||||
|
||||
wmbusmeters = pkgs.stdenv.mkDerivation {
|
||||
pname = "wmbusmeters";
|
||||
version = "unstable-2026";
|
||||
src = pkgs.fetchFromGitHub {
|
||||
owner = "wmbusmeters";
|
||||
repo = "wmbusmeters";
|
||||
rev = "85532d91fd1e2bfa25b01705dd6aa574287649f7";
|
||||
hash = "sha256-rOeeeYVXxGTXdKQMHr/bkODoi6rlE4i3r7ItGhyimjI=";
|
||||
};
|
||||
nativeBuildInputs = [ pkgs.pkg-config ];
|
||||
buildInputs = [ pkgs.rtl-sdr ];
|
||||
makeFlags = [ "PREFIX=$(out)" ];
|
||||
# skip install of systemd units etc.
|
||||
installPhase = ''
|
||||
runHook preInstall
|
||||
install -Dm755 build/wmbusmeters $out/bin/wmbusmeters
|
||||
runHook postInstall
|
||||
'';
|
||||
};
|
||||
|
||||
pythonEnv = pkgs.python3.withPackages (ps: with ps; [
|
||||
pyserial
|
||||
numpy
|
||||
]);
|
||||
in
|
||||
{
|
||||
packages.${system} = { inherit rtl-wmbus wmbusmeters; };
|
||||
|
||||
devShells.${system}.default = pkgs.mkShell {
|
||||
name = "heltec-repeater-dev";
|
||||
buildInputs = [
|
||||
esp-dev.packages.${system}.esp-idf-esp32s3
|
||||
pkgs.rtl-sdr
|
||||
rtl-wmbus
|
||||
wmbusmeters
|
||||
pythonEnv
|
||||
pkgs.usbutils
|
||||
pkgs.picocom
|
||||
pkgs.jq
|
||||
];
|
||||
};
|
||||
};
|
||||
}
|
||||
Reference in New Issue
Block a user